PR=r2

DEPENDS = readline

SRC_URI := "http://hostopia.samba.org/samba/ftp/old-versions/samba-${PV}.tar.gz \
	   file://${FILESDIR}/configure.patch;patch=1"
S := ${WORKDIR}/${P}/source

PACKAGES =+ "libsmbclient libsmbclient-dev smbclient"
FILES_libsmbclient = "${libdir}/libsmbclient.so.* /etc/smb.conf"
FILES_libsmbclient-dev = "${libdir}/libsmbclient.so ${includedir}"
FILES_smbclient = "${bindir}/smbclient \
                   ${bindir}/nmblookup \
                   ${bindir}/smbmount \
                   ${bindir}/smbumount \
                   ${bindir}/smbmnt \
                   ${libdir}/*.dat"

inherit autotools

EXTRA_OECONF='--disable-cups --with-readline=${STAGING_LIBDIR}/.. \
	      --without-ads --without-automount --with-smbmount \
	      --with-configdir=/etc'
do_configure_prepend () {
	./script/mkversion.sh
	if [ ! -e acinclude.m4 ]; then
		cat aclocal.m4 > acinclude.m4
	fi
}

do_install_append() {
	mv ${D}${libdir}/libsmbclient.so ${D}${libdir}/libsmbclient.so.0
	ln -sf libsmbclient.so.0 ${D}${libdir}/libsmbclient.so
	rm -f ${D}${bindir}/*.old
	rm -f ${D}${sbindir}/*.old
	mkdir -p ${D}/etc
	touch ${D}/etc/smb.conf

	chmod +s ${D}${bindir}/smbmnt
	chmod +s ${D}${bindir}/smbumount
}

do_stage() {
	install -m 0644 include/libsmbclient.h ${STAGING_INCDIR}
	oe_libinstall -C bin -a -so libsmbclient ${STAGING_LIBDIR}
}